“ArduFarmBot 2” – Sistema automático para irrigação e calor, agora com o NodeMCU e Blynk

Com base em dados recolhidos de uma plantação qualquer tais como, temperatura e humidade, tanto do ar quanto do solo, o ArduFarmBot 2 decidirá a quantidade certa (e quando) a planta deve receber calor e água. O sistema deverá também permitir a intervenção manual de um operador para controlar uma bomba de água e uma lâmpada elétrica para gerar calor para a plantação. Esta intervenção manual deverá ser possível de ser executada tanto no local como remotamente via Internet.

O sistema deverá receber como:

A- Entrada:

Sensores:

• Temperatura do ar
• Humidade Relativa ao Ar
• Temperatura do solo
• Humidade do solo

Botões:

• Bomba ON / OFF
• Lâmpada ON / OFF

B- Saída:

Atuadores:

• Relé para controle da bomba
• Relé para controle de lâmpada

Mensagens automáticas devem ser enviadas na ocorrência de eventos, tais como:

• Bomba LIGADA
• Lâmpada LIGADA
• Sistema off-line

Exibição de dados

• Todos os dados analógicos e digitais devem estar disponíveis para avaliação imediata

Armazenamento de dados

• Dados históricos devem ser armazenados remotamente

O diagrama de blocos abaixo mostra os principais componentes do projeto.

 Lista de materiais:

• Placa NodeMcu WiFii ESP 12-F
• Sensor de temperatura e Humidade Dht22 AM2302
• Sensor de Humidade do Solo Terra
• Sensor de Temperatura à prova de água
• Ecrã Display LCD
• Botão de pressão colorido (3x)
• Led de 3 mm (3x)
• Módulo Relé
• Cabos Jumper
• Resistência 4.7KΩ
• Resistência 10kΩ
• Resistência 220Ω
• Fonte de alimentação 5V/ 2A

O NodeMCU

O NodeMCU ESP-12E é a versão integrada do popular ESP8266, um Serial to Wi-Fi System On a Chip (SoC), que apareceu pela primeira vez em 2013 e lançado no mercado já no ano seguinte. O ESP8266 foi desenvolvido pela empresa chinesa com sede em Shangai, Espressif Systems, uma fabricante de circuitos integrados focada no desenvolvimento de chips de RF, particularmente Wi-Fi.

Existem vários módulos no mercado que se utilizam do chip ESP8266. Eles são nomeados ESP-NN, onde NN é um número 01, 02, … .. 12, etc. e as vezes seguido de uma letra. Estes módulos tipicamente possuem: o ESP8266 SoC, memória flash, um cristal e na maioria dos casos, uma antena. No link poderá encontrar a lista completa de dispositivos baseados no ESP8266 encontradas no mercado: Família ESP8266.

Os 2 módulos mais importantes são sem dúvida, a ESP-01 e o ESP-12E. No ArduFarmBot 2, usaremos o: ESP-12E Development Board (NodeMCU DevKit 1.0)

Para aumentar ainda mais a capacidade de utilização do módulo ESP-12E, foram adicionados regulação de potência e conectividade USB. O ESP-12E inclui:

• Adaptador USB para UART: Silicon Labs CP2102.
• NCP1117 3,3VDC Voltage Regulator.
• Conector micro-USB.
• Pinos adicionais com GND, Vin, 3,3VDC para facilitar o acesso durante o desenvolvimento.

O NodeMCU ESP-12E é um dispositivo pronto para ser usado, basta que instale os drivers USB no seu computador e comece a escrever programas que se conectam à sua rede Wi-Fi.

• Suporte STA / AP / STA + AP 3 modos de funcionamento;
• Pilha de protocolo TCP / IP embutida, suporte a conexão de cliente TCP de múltiplos canais (máximo 5);
• 0 ~ D8, SD1 ~ SD3: usado para GPIO, PWM (D1-D8), IIC, ect; A capacidade dirigida pode ser alcançada em 15mA;
• AD0: ADC de 10 bits de sentido único;
• Entrada de energia: 4.5V ~ 9V (10VMAX), suporta USB alimentado e USB debug;
• Corrente de trabalho: ≈ 70mA (200mA MAX, continuar), em espera <200uA;
• Taxa de dados de transmissão: 110-460800bps;
• Suporta interface de comunicação de dados UART / GPIO;
• Apoie o firmware de atualização remotamente (OTA);
• Suporte Smart Link;
• Temperatura de trabalho: -40 ℃ ~ + 125 ℃;
• Modo Driven: ponteira H de grande potência
• Peso: 7g.

Instalando o NodeMCU com o Arduino IDE

Se já tiver o NodeMCU instalado com o IDE, ignore esta etapa!

Se deseja programar e usar o NodeMCU como se fosse um Arduino, a boa notícia é que é possível escrever-se firmwares personalizados e carregá-los no chip (“flash-it”). É importante lembrar que qualquer novo “firmware personalizado” irá substituir qualquer coisa previamente armazenada na memória flash do chip, incluindo o firmware original carregado em fábrica (aquele que aceita os comandos AT). Embora possamos usar o SDK do fabricante para o desenvolvimento de firmwares personalizados, é muito mais fácil usar o bom e velho Arduino IDE.

Comecemos:

No Arduino IDE, abra a janela de preferências e digite a URL (marcado em vermelho na foto abaixo) no campo Additional Boards Manager URLs e selecione OK.

http://arduino.esp8266.com/stable/package_esp8266com_index.json

• Selecione MENU → Tools → Board → Boards Manager…e vá rolando até encontrar a opção: esp8266 by ESP8266 Community , a qual deverá ser o último item da lista e clique INSTAL
  

Instalando USB Drivers: O USB to Serial UART module incluído no dispositivo, é o Silicon Labs’ CP2102, para o qual deveremos instalar o driver Virtual COM Port (VCP). No caso de meu MAC, o arquivo criado para comunicar com o CP2102 foi: /dev/cu.SLAB_USBtoUART. Pode encontrar o driver apropriado ao seu computador no seguinte link: CP210x USB to UART Bridge VCP Drivers

Depois de restartar o Arduino IDE , poderemos selecionar a placa no menu: Option Tools → Board → NodeMCU 1.0 (ESP-12E Module). Em seguida, especificar a correta frequência de operação da CPU: (Tools → CPU Frequency: “” → 80MHz) e velocidade de comunicação (Tools → Upload Speed: “” → 115,200). Finalmente, selecionar o port apropriado ao seu computador: (Tools → Port → /dev/cu.SLAB_USBtoUART).

Neste ponto estamos prontos para escrever nosso próprio firmware e enviá-lo ao dispositivo, mas vamos primeiramente tentar um dos exemplos incluídos com a biblioteca: File → Examples → ESP8266WiFi → WiFiScan. Após o upload, podemos abrir a janela do Serial Monitor e observar os resultados. Verifique que 115,200 baud é a velocidade selecionada no menu do canto inferior direito do Serial Monitor.

Instalando o Display OLED

Um grande companheiro para o nosso ESP-12E é o pequeno display do tipo OLED: SSD 1306. Ele será muito útil ao projeto, mostrando localmente os dados capturados, mensagens, etc. O modelo usado é um display de 128 x 64 pixels que se comunica via I2C, o SSD 1306, cujas principais características são:

• 128 pixels na horizontal por 64 pixels na vertical. Assim se usar por exemplo, caracteres de 8×8 pixels, obteremos um display de “16X8” (8 linhas de 16 caracteres cada).
• Comunicação via I2C : se deve conectar ao NodeMCU I2C pins, usando:

– SCL ==> D1 (equ. Arduino 5)
– SDA ==> D2 (equ. Arduino 4)

Outra característica importante do SSD1306 é que pode alimentar-lo com 3.3V gerado diretamente pelo módulo nodeMCU, como via um Power Suppley externo de 5V, que será como faremos no projeto.

Uma vez conectado o display, deve baixar e instalar sua biblioteca ao Arduino IDE. Nós usaremos a versão ACROBOT abaixo:

SSD1306 Arduino Library

Depois de ter reiniciado o IDE, a biblioteca deverá estar instalada. Carreguemos o sketch abaixo para testar o display OLED:

/***********************************************************************
* NodeMCU and OLED display "Hello World"
* Based on original code developed by: Makerbro at https://acrobotic.com/
* MJRoBot 12Oct16
************************************************************************/

#include 
#include 

void setup()
{
 Wire.begin(); 
 oled.init(); // Initialze SSD1306 OLED display
 oled.clearDisplay(); // Clear screen
 oled.setTextXY(0,0); // Set cursor position, start of line 0
 oled.putString(" MJRoBot.org");
 oled.setTextXY(4,0); // Set cursor position, start of line 4
 oled.putString(" HELLO, WORLD");
}

void loop()
{
}

Observe, que quando não definir um tamanho em pixels para os caracteres de texto, o padrão será 8X8. Para se definir um tamanho diferente, por exemplo,5X7, você poderá utilizar: oled.setFont(font5x7);

Abaixo o código para o “Hello World”:

OLED_test.ino

Captura da temperatura do ar e humidade

Um dos sensores mais utilizados para a captura de dados meteorológicos é o DHT22 (ou seu irmão, o DHT11), um sensor digital de humidade relativa do ar e temperatura. Ele usa internamente um sensor capacitivo de humidade e um termistor para medir o ar circundante, gerando um sinal digital em sua saída de dados.

De acordo com a sua folha de dados (Datasheet), o sensor deve ser alimentado entre 3.3V e 5V (algumas especificações falam em até 6V max). Ele trabalha a partir de -40 a + 80 graus centígraods (algumas especs falam em + 125 ° C) com uma precisão de +/- 0,5 ° C de temperatura e +/-2% de umidade relativa. É importante ter em mente que o seu (“sencing period”) é em média de dois segundo (tempo mínimo entre leituras).

O DHT22 tem 4 pinos (de frente para o sensor, o pino 1 é o mais esquerda):

• VCC (5V externo)
• Saída de dados
• Não conectado
• GND (Terra)

Uma vez que normalmente usará o sensor em distâncias inferiores a 20m, uma resistência de 10K deve ser conectado entre os pinos de dados e o VCC. O pino de saída deve ser conectado ao pino D3 do ESP-12E (veja o diagrama acima).

Uma vez que o sensor esteja instalado fisicamente no NodeMCU, baixe a biblioteca DHT a partir do repositório de programas: Adafruit github e a instale junto as outras bibliotecas de seu IDE (ambiente de desenvolvimento de programas do Arduino).

Uma vez que  recarregue o IDE, a biblioteca para o sensor de DHT deverá aparecer como instalada. Execute o código abaixo para verificar se tudo está funcionando OK:

NodeMCU_DHT22_IoT_Local_Station_OLED.ino

Capturando a humidade do solo

No projeto ArduFarmBot,  exploramos como trabalhar com um Higrômetro para medir-se a humidade do solo. Na ocasião, exploramos como desenvolver um sensor caseiro, porém aqui para explorarmos outras alternativas, usaremos um do tipo electrónico, muito comum no mercado: o sensor YL-69 + LM393 (módulo comparador). O módulo LM393 tem 2 saídas, uma digital (D0) que pode ser configurada usando-se um potenciómetro integrado e um analógico (A0). Este módulo pode ser tanto alimentado com 3.3V (o que é muito conveniente quando se trabalha com um NodeMCU), quanto com 5V externo.

• LM393 A0: ao NodeMCU A0
• LM393 VCC: ao VCC 5V externo (ou ao NodeMCU D8) Vide Nota abaixo *
• LM393 GND: ao NodeMCU GND
• LM393 D0: Não conectado

(*) É importante destacar que o correto é conectar-se o VCC do Sensor a um Pino Digital do NodeMCU, definido como saída, de maneira a que o LM393 seja “alimentado” somente quando precisemos de uma leitura. Isto é importante não apenas para economizar energia, mas também para evitar a corrosão das sondas. Utilizando-se um sensor caseiro como foi o caso no projeto ArduFarmBot original, o sensor funcionaria sem problemas, mas tendo-se que alimentar o módulo comparador, o NodeMCU apresentou problemas com o  “soilMoisterVcc” conectado. Assim, conectei o LM393 direto a VCC (5V) externo como mostrado no diagrama elétrico acima  o código não precisa ser alterado).

Abaixo, rotina para ler o sensor conectado à porta analógica:

/***************************************************
 * Get Soil Moister Sensor data
 **************************************************/
void getSoilMoisterData(void)
{
  soilMoister = 0;
  digitalWrite (soilMoisterVcc, HIGH);
  delay (500);
  int N = 3;
  for(int i = 0; i < N; i++) // read sensor "N" times and get the average
  {
    soilMoister += analogRead(soilMoisterPin);   
    delay(150);
  }
  digitalWrite (soilMoisterVcc, LOW);
  soilMoister = soilMoister/N; 
  Serial.println(soilMoister);
  soilMoister = map(soilMoister, 600, 0, 0, 100); 
}

Alguns comentários sobre a rotina acima:

• O dado do sensor é capturado 3 vezes, tirando-se uma média das mesmas.
• Usamos MAP para configurar o intervalo em percentagem. Para definir os valores extremos, procedemos como abaixo:
  – Fazer um “curto-circuito” nas pontas de prova do higrómetro, isso equivalente a “100% de h
• humidade”, o que gerará um valor de cerca de 0 na saída do ADC
  – Colocar o higrómetro”no ar”, se observa que o valor exibido no Serial Monitor, que em meu caso foi em torno de 600.

Abaixo um código parcial para os testes até esta etapa do projeto:

FP6AH1NIU5NCAPI.ino

Capturando a temperatura do solo

Nas minhas experiências com o ArduFarmBot, descobri que existe uma relação grande entre a a humidade e a temperatura do solo. Assim, deixarei aqui opcionalmente, um sensor para temperaturas de solo, caso deseje aprofundar no assunto. Mas importante ressaltar que para o accionamento do rego, usaremos somente a temperatura do ar, proporcionada pelo DHT22.

Usaremos no projeto, uma versão impermeabilizada do sensor DS18B20. Isso é importante, pois o usaremos um solo húmido. O sensor é isolado e pode tomar medidas até 100oC , como recomendado pela Adafrut.

O DS18B20 é um sensor digital, o que o torna ideal para o uso em longas distâncias! Estes sensores digitais de temperatura tipo “1-Wire” são bastante precisos (± 0,5 ° C em grande parte da gama) e podem fornecer até 12 bits de precisão à partir de seu conversor digital-analógico integrado. Eles funcionam muito bem com o NodeMCU usando um único pino digital, e pode até mesmo conectar vários sensores no mesmo pino, pois cada um possui um ID único de 64 bits gravado de fábrica, para poder diferenciar-los.

• O sensor funciona de 3,0 a 5,0V.
• O sensor tem 3 fios:
  – Preto: GND
  – Vermelho: VCC
  – Amarelo: dados de 1 fio

Aqui, pode encontrar os dados completos: DS18B20 Datasheet

Para usar o DS18B20 com o IDE do Arduino, importe as bibliotecas abaixo e instale no seu IDE:

• OneWire (NOTE 1)

• DallasTemperature

Para testar o sensor, pode usar o código “Simple.ino” incluído nos Exemplos da Biblioteca, como mostrado na foto acima. Carregue o código no seu NodeMCU e monitore a temperatura usando o Monitor Serial.

foto acima mostra o resultado esperado. Segure o sensor em sua mão, você deve ver a temperatura mudar para cerca de 32 / 34oC.

NOTA: A biblioteca OneWire DEVE ser uma versão especial, modificada para ser usada com o ESP8266, caso contrário receberá um erro durante a compilação. Encontrará a última versão no link acima ou no arquivo zip abaixo:

 Completando o HW

Seguindo o diagrama acima, complete o HW, instalando os botões e LEDs.

Lembre-se que ao usar os pinos que fornecem 3.3V do NodeMCU para alimentar outros dispositivos pode tornar o sistema instável devido ao consumo de corrente.Tudo bem quando temos somente um ou dois dispositivos externos, mas no caso de nosso projeto, vários componentes estão sendo utilizados. Verifique que todos os sensores (DHT22, DS18B20 e LM393 / YL69) e o Display OLED estão alimentados corretamente, através do 5V externo e o NodeMCU penas fornecendo os sinais de controle.

LEDs

Observe que os LEDs conectados ao NodeMCU são somente para serem usados como teste. Eles “simularão”, a bomba (LED vermelho) e a lâmpada (LED verde). Na configuração final, relés serão conectados a essas saídas como descrito na próxima etapa.

Botões

Com base nas leituras de sensores, um operador pode também decidir controlar manualmente a Bomba e / ou a Lâmpada. Para isso, três botões serão incorporados ao projeto:

• VERMELHO: Ctrl da bomba manual
• VERDE: Lâmpada manual Ctrl
• AMARELO: Botão para leitura e apresentação de dados dos sensores (será detalhado na próxima etapa)

Os botões funcionam em modo “alterno”, ou “Toggle”. Se um atuador estiver “LIGADO”, pressionar o botão irá desligár-lo e vice-versa. A lógica do botão será “normalmente fechada”, o que significa que a Entrada NodeMCU estará constantemente “HIGH”. Pressionando o botão, um “LOW” será aplicado no pino específico.

O Diagrama abaixo resume os pinos do NodeMCU e sua conexão aos dispositivos.

Para verificar se existe um “comando local”, ou seja se um botão foi pressionado, a função readLocalCmd() deve ser executada. Esta função lê cada botão, atualizando o status das variáveis correspondentes aos estados dos atuadores (pumpStatus e lampStatus). Observe que em vez de executar diretamente um comando digitalRead (pin), a função debounce(pin) é chamada. Isso é para evitar leituras falsas do botão.

/****************************************************************
* Read local commands (Pump and Lamp buttons are normally "HIGH"):
****************************************************************/
void readLocalCmd() 
{  
  boolean digiValue = debounce(PUMP_ON_BUTTON);
  if (!digiValue) 
  {
    pumpStatus = !pumpStatus;
    aplyCmd();
  }

  digiValue = debounce(LAMP_ON_BUTTON);
  if (!digiValue) 
  {
    lampStatus = !lampStatus;
    aplyCmd();
  }
}

No caso em que um botão é pressionado, outra função será chamada: aplyCmd (). E como o nome diz, esta aplicará o comando correspondente, ativando ou desativando os atuadores:

/***************************************************
* Receive Commands and act on actuators
****************************************************/
void aplyCmd()
{
if (pumpStatus == 1)
{
digitalWrite(PUMP_PIN, HIGH);
displayData();
}
else
{
digitalWrite(PUMP_PIN, LOW);
displayData();
}

if (lampStatus == 1)
{
digitalWrite(LAMP_PIN, HIGH);
displayData();
}
else
{
digitalWrite(LAMP_PIN, LOW);
displayData();
}
}

Considerações acerca do código:

Quando pensamos sobre o 4 grandes “grupo de tarefas” desenvolvidos até agora, podemos resumir-los em:

• Ler Sensores
• Ler Botões (comando local)
• Atuar na bomba / lâmpada
• Exibir dados

Perceberemos que o momento em que devemos realizar essas tarefas não são necessariamente os mesmos. Por exemplo, para ler os dados de temperatura e umidade do DHT 22, teremos que esperar pelo menos 2 segundos entre uma medida e outra, mas se esperamos alguns minutos, isto não fará diferença no projeto final. Para o sensor de umidade do solo, quanto menos medições fizermos, melhor (diminui a corrosão das sondas geradas por eletrólise). Mas quando pensamos nos atuadores, logo que pressionamos um botão, gostaríamos (e possivelmente precisaremos) de uma reação rápida.

Portanto, devemos usar aqui um “timer” para controlar corretamente o timing correto dessas tarefas. Poderíamos fazer isso usando o millis (), como fizemos no projeto ArdFarmBot original, mas aproveitaremos para conhecer outra ótima ferramenta, o SimpleTimer.h (siga as instruções no link ao lado para instalar a Biblioteca: SimpleTimer)

A biblioteca deve ser incluída no corpo principal do seu código, seguido de uma definição para o Timer do projeto:

 SimpleTimer timer;

Em seguida, defina os temporizadores:

timer.setInterval(1000L, readLocalCmd);       // Read buttons at every 1 second
  timer.setInterval(2000L, getSoilTempData);    // Read Soil Temp at every 2 seconds
  timer.setInterval(2000L, getDhtData);         // Read DHT Sensor at every 2 seconds
  timer.setInterval(10000, getSoilMoisterData); // Read Soil Humidity at every 10 seconds
  timer.setInterval(10000, displayData);        // Display Data at OLED at every 10 seconds

ArduFarmBot 2, “Contrôle Local”- Concluindo o código

Apresentando o Botão para Leitura dos sensores (“O amarelo”)

Como observamos na última etapa, precisaremos aguardar ciclos longos entre as medições do sensor de umidade do solo. Isto está bem para as nossas necessidades automáticas, mas para uma operação manual não vamos querer “esperar” 10, 15 ou mais segundos (ou mesmo minutos no caso real) para atualizar a leitura de um sensor. Também no mundo real, não faz sentido manter o display OLED “ACESO” ou “ON”, o tempo todo. Assim, o normal será “APAGADO” ou “OFF”.

Introduziremos esse 3 ª botão ao nosso projeto, o qual permitirá exibir os dados de leitura dos sensores a qualquer momento que quisermos, independentemente do tempo das leituras automáticas. Além disso, usaremos este mesmo botão para exibir dados no OLED quando os sensores forem atualizados. Abaixo da função readLocaCmd () alterada para interação com o novo botão:

/**************************************************************************
* Read local commands (Pump, Lamp and Sensor buttons are normally "HIGH"):
**************************************************************************/
void readLocalCmd() 
{  
  boolean digiValue = debounce(PUMP_ON_BUTTON);
  if (!digiValue) 
  {
    pumpStatus = !pumpStatus;
    aplyCmd();
  }

  digiValue = debounce(LAMP_ON_BUTTON);
  if (!digiValue) 
  {
    lampStatus = !lampStatus;
    aplyCmd();
  }

  digiValue = debounce(SENSORS_READ_BUTTON);
  if (!digiValue) 
  {
    turnOffOLED = !turnOffOLED;
    if (!turnOffOLED)
    {
      oled.setTextXY(0,0); oled.putString("UPDATING SENSORS");
      getDhtData();
      getSoilMoisterData();
      getSoilTempData();
      oledStart();
      displayData();
    }else oled.clearDisplay(); //turn off OLED
  }
}

Neste ponto, todo o HW está completado (usando-se LEDs como atuadores) e temos portanto todas as peças de SW à serem montadas.

O vídeo mostra o ArduFarmBot 2, operando em modo Local e Manual:

Poderá fazer o download do código a ser utilizado na versão “Controle local”, diretamente em meu repositório:  GitHub: ArduFarmBot2_Local_Manual_Ctrl_V1

Automatizando nosso sistema de jardinagem

Neste ponto, todos os componentes do HW estão no lugar e como se viu na etapa anterior, o ArduFarmBot 2 pode ser controlado localmente por um operador através dos botões. O que falta agora é definir-se a “lógica” que permitirá ao nosso sistema realizar a tarefa de irrigar a plantação automaticamente! Para isto, precisamos incluir algum “cérebro” ao nosso projeto.

Para começar, definamos o intervalo inicial onde funcionarão os sensores. Esses valores devem ser alterados mais tarde usando-se valores práticos a serem obtidos em uma plantação real:

Humidade do solo:

• “HÚMIDO”: Mais de 88% (não regar)
• “IDEAL”: Entre 66% e 88% (Onde queremos trabalhar)
• “SECO”: abaixo de 66% (necessário ligar a bomba para aumentar a humidade)

Temperatura do ar:

• “FRIO”: Abaixo de 12oC (Ligar a lâmpada para gerar calor)
• “IDEAL”: entre 12oC e 22oC
• “QUENTE”: Acima d 22oC (não ligar a lâmpada)

Deve levar em conta que cada tipo de semente possui um intervalo ótimo de temperatura onde germinarão mais rapidamente. Por exemplo, para tomates o tempo mínimo para germinar as sementes será de 6 dias em temperaturas entre 20 e 25 oC, sendo que esta quantidade de dias aumentará para temperaturas inferiores ou superiores (mais de 43 dias para temperaturas inferiores a 10oC e 9 dias para temperaturas superiores a 35oC.

Poderá verificar mais informações sobre este relacionamento (Temp / dias de germinação) no link abaixo:

The effect of soil temperature on seeds germination

Uma vez de posse desses dados: temperatura do ar, umidade do ar, umidade do solo e temperatura do solo, poderemos construir uma matriz complexa definindo como queremos que o nosso sistema de jardinagem automático funcione.

Definamos os parâmetros à serem usados em nosso código:

/* Automatic Control Parameters Definition */
#define DRY_SOIL      66
#define WET_SOIL      85
#define COLD_TEMP     12
#define HOT_TEMP      22
#define TIME_PUMP_ON  15
#define TIME_LAMP_ON  15

TIME_PUMP_ON e TIME_LAMP_ON são definidos como o tempo em segundos que a bomba e a lâmpada devem permanecer LIGADAS durante a operação automática.

Com base nos parâmetros acima, pensemos em algumas suposições muito simples a serem implementadas no código:

• Se o solo estiver seco: (DRY) ==> Ligar a bomba (PUMP = ON)
• Se a temperatura estiver fria (COLD) ==> Ligar a lâmpada (LAMP = ON)

O código:

Criemos uma nova função, que com base na leitura dos sensores lidará automaticamente com os atuadores, ligando / desligando a bomba e a lâmpada: autoControlPlantation (). Esta função conforme mostrado abaixo, será chamada em todas os ciclos de leitura de sensores:

/**************************************************************
* Automatically Control the Plantation based on sensors reading
**************************************************************/
void autoControlPlantation(void)
{ 
  if (soilMoister < DRY_SOIL) 
  {
    turnPumpOn();
  }

  if (airTemp < COLD_TEMP) 
  {
    turnLampOn();
  }
}

A função tem duas tarefas básicas:

• Controlar a bomba
• Controlar a lâmpada

Abaixo as duas funções de controle chamadas a partir da função autoControlPlantation ():

***************************************************
* Turn Pump On for a certain amount of time
****************************************************/
void turnPumpOn()
{
  pumpStatus = 1;
  aplyCmd();
  delay (TIME_PUMP_ON*1000);
  pumpStatus = 0;
  aplyCmd();
}

/***************************************************
* Turn Lamp On for a certain amount of time 
****************************************************/
void turnLampOn()
{
  lampStatus = 1;
  aplyCmd();
  delay (TIME_LAMP_ON*1000);
  lampStatus = 0;
  aplyCmd();
}

Por fim, usaremos o botão Sensor Read (“amarelo”) para não só interromper o programa durante um certo tempo durante a inicialização, mas também para exibir os parâmetros iniciais mais importantes, como mostrado na foto acima.

Neste ponto, o ArduFarmBot está totalmente funcional em termos de HW e SW.

O vídeo mostra o ArduFarmBot 2, operando em modo Local e Automático:

O código para a versão  “Local e Automático” do ArduFarmBot2 pode ser descarregada  de meu depositário:  GitHub: ArduFarmBot2_Local_Automatic_Ctrl_V2.

 Criando a App BLYNK

char auth[] = "YOUR PROJECT TOKEN"; // Blynk project: "ArduFarmBot2"
char ssid[] = "YOUR LOCAL WIFI NAME";
char pass[] = "YOUR WIFI PASSWORD";

WidgetLED PUMPs(V0);  // Echo signal to Sensors Tab at Blynk App
WidgetLED PUMPa(V5); // Echo signal to Actuators Tab at Blynk App
WidgetLED LAMPs(V1);  // Echo signal to Sensors Tab at Blynk App
WidgetLED LAMPa(V6); // Echo signal to Actuators Tab at Blynk App

/***************************************************
* Receive Commands and act on actuators
****************************************************/
void aplyCmd()
{
  if (pumpStatus == 1) 
  {
    Blynk.notify("ArduFarmBot2: Warning ==>> Pump ON"); 
    digitalWrite(PUMP_PIN, HIGH);
    if (!turnOffOLED) displayData();
    PUMPs.on();
    PUMPa.on();
  }
  else
      {
        digitalWrite(PUMP_PIN, LOW);
        if (!turnOffOLED) displayData();
        PUMPs.off();
        PUMPa.off();
      }
  
  if (lampStatus == 1) 
  {
    Blynk.notify("ArduFarmBot2: Warning ==>> Lamp ON");
    digitalWrite(LAMP_PIN, HIGH);
    if (!turnOffOLED) displayData();
    LAMPs.on();
    LAMPa.on();
  }
  else
      {
        digitalWrite(LAMP_PIN, LOW);
        if (!turnOffOLED) displayData();
        LAMPs.off();
        LAMPa.off();
      }
}

/****************************************************************
* Read remote commands 
****************************************************************/
BLYNK_WRITE(3) // Pump remote control
{
  int i=param.asInt();
  if (i==1) 
  {
    pumpStatus = !pumpStatus;
    aplyCmd();
  }
}

BLYNK_WRITE(4) // Lamp remote control
{
  int i=param.asInt();
  if (i==1) 
  {
    lampStatus = !lampStatus;
    aplyCmd();
  }
}

digitalWrite(PUMP_PIN, HIGH); // To be used with Relay module (inverted logic: normally HIGH)
digitalWrite(LAMP_PIN, HIGH); // To be used with Relay module (inverted logic: normally HIGH)

/***************************************************
* Receive Commands and act on actuators
****************************************************/
void aplyCmd()
{
  if (pumpStatus == 1) 
  {
    Blynk.notify("ArduFarmBot2: Warning ==>> Pump ON"); 
    digitalWrite(PUMP_PIN, LOW); // To be used with Relay module (inverted logic: activate with LOW)
    if (!turnOffOLED) displayData();
    PUMPs.on();
    PUMPa.on();
  }
  else
      {
        digitalWrite(PUMP_PIN, HIGH); // To be used with Relay module (inverted logic: normally HIGH)
        if (!turnOffOLED) displayData();
        PUMPs.off();
        PUMPa.off();
      }
  
  if (lampStatus == 1) 
  {
    Blynk.notify("ArduFarmBot2: Warning ==>> Lamp ON");
    digitalWrite(LAMP_PIN, LOW); // To be used with Relay module (inverted logic: activate with LOW)
    if (!turnOffOLED) displayData();
    LAMPs.on();
    LAMPa.on();
  }
  else
      {
        digitalWrite(LAMP_PIN, HIGH); // To be used with Relay module (inverted logic: normally HIGH)
        if (!turnOffOLED) displayData();
        LAMPs.off();
        LAMPa.off();
      }
}

Comments

Comentários